Import files to individual layers

jdavison

See Appendix A – Batch Import Script for code required for this section.

Sometimes it can be handy to import STL files as separate layers in RhinoCAD. This means you can treat each layer individually when repairing geometry. To do this in rhino, download or save the script in Appendix A – Batch Import Script, to a .rvb file. This means to copy the code to a new text document, save it and possibly change the file extension, to .rvb. Save this file anywhere you like. Then, in Rhino, select tools then click on RhinoScript, followed by clicking Load. You will need to navigate to the file containing the script we just saved. Note that once a script is loaded, it can be run by selecting Run here instead. The rest is easy, a dialogue will come up asking for the directory of the files you wish to import. You will need to select the correct file extension (in this example, the files are .stl). Rhino will then import the geometries in the folder to individual layers. Figure 12 demonstrates how this can then be viewed in Rhino. From here, individual layers can be selected by:

Selecting all the layers
Right clicking and turning all layers off
Clicking the lightbulb of the layer you wish to turn on. See Figure 13 for help
From here, you can perform many functions, but for now, try typing the _SelAll command, followed by _ReduceMesh. You will see that the mesh of just this layer is reduced. Simply turn on the next layer and repeat. These commands can also be entered into the MacroEditor (command _MacroEditor). This tool will loop all commands entered into it when you hit the “play” button (see Figure 14) . In our case, we’ve used the select all and reduce mesh commands but this also applies to other commands.

FIGURE 12 - RHINO - RUN A SCRIPT

FIGURE 13 - STLS IMPORTED TO SEPARATE LAYERS

FIGURE 14 - SELECTING INDIVIDUAL LAYERS

FIGURE 15 – MACRO EDITOR

jdavison

Hey James that was a really cool tutorial. Can you explain without saying “umm”, next time?

jdavison

Option Explicit
'Script written by Mitch
'Script version 12 September 2013
'added alternate file extensions for STEP and IGES

Private strOldFolder
If isEmpty(strOldFolder) Then
	strOldFolder = Rhino.WorkingFolder
End If

Call BatchImportGen

Sub BatchImportGen()
    
	' Allow the user to interactively pick a folder
	Dim strFolder
	strFolder = Rhino.BrowseForFolder(strOldFolder, "Select folder to process", "Batch Import")
	If VarType(strFolder) <> vbString Then 
		Exit Sub
	Else strOldFolder = strFolder
	End If	
  
	' Create a file system object
	Dim objFSO
	Set objFSO = CreateObject("Scripting.FileSystemObject") 
  
	' Get a folder object based on the selected folder
	Dim objFolder
	Set objFolder = objFSO.GetFolder(strFolder)
	
	Dim strExt,strAltext,arrExt
	arrExt = Array("Rhino", "STL", "DXF", "DWG", "IGES", "STEP", "SolidWorks")
	strExt = Rhino.ListBox(arrExt, "Select File type", "Batch Import")
	strAltExt = ""
	If IsNull(strExt) Then Exit Sub	
	
	Select Case strExt
		Case "Rhino"
			strExt = "3dm"
		Case "STEP" 
			strExt = "stp"
			strAltExt = "step"
		Case "SolidWorks"
			strExt = "sldprt"
		Case "IGES"
			strExt = "igs"
			strAltExt = "iges"
		Case Else
			strExt = LCase(strExt)
	End Select
		
	' Process the folder
	Call ProcessFolder(objFSO, objFolder, strExt, strAltExt)
  
	' Release the objects
	Set objFolder = Nothing
	Set objFSO = Nothing
  
End Sub
  
  '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  ' ProcessFolder
  '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub ProcessFolder(objFSO, objFolder, ext, altExt)
	Rhino.EnableRedraw(False)
	' Import all files of chosen filetype in the selected folder
	Dim objFile,eName,strOpen,strFilename,strLayername,arrLCO,blnFound
	blnFound = False
	For Each objFile In objFolder.Files
		eName = LCase(objFSO.GetExtensionName(objFile.Path))
		If eName <> "" And (eName = ext Or eName = altExt) Then		
			strOpen = LCase(objFile.Path)
			strFilename = objFile.Name
			strLayername = Left(strFilename, (Len(strFilename) - Len(ext) - 1))
			Call Rhino.Print("Importing " & strLayername)
			Call Rhino.Command("_NoEcho _-Import " & chr(34) & strOpen & chr(34) & " _Enter")
			arrLCO = Rhino.LastCreatedObjects(False)
			'add new layer for each file with layer name=file name (less extention)
			If IsArray(arrLCO) Then				
				If Not Rhino.IsLayer(strLayername) Then
					Rhino.AddLayer(strLayername)
				End If
				Call Rhino.ObjectLayer(arrLCO, strLayername)
			Else
				Call Rhino.Print("No objects imported from file " & strFileName)
			End If
			blnFound = True			
		End If
	Next
	If Not blnFound Then
		Call Rhino.MessageBox("No files of chosen type found in folder!", 0, "File Import")
	End If
	Rhino.EnableRedraw(True)
End Sub